home *** CD-ROM | disk | FTP | other *** search
/ Macwelt 4 / Macwelt DVD 4.cdr / Entwickler / Mac-OS / oxygen / samples / docbook / xsl / common / labels.xsl < prev    next >
Encoding:
Extensible Markup Language  |  2002-09-09  |  18.9 KB  |  555 lines  |  [□□□□/□□□□]
  2. labels.xslI-π¢tÚπ¢tÚÅÅÎ8<?xml version='1.0'?>
  3. <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  4.                 xmlns:doc="http://nwalsh.com/xsl/documentation/1.0"
  5.                 exclude-result-prefixes="doc"
  6.                 version='1.0'>
  7.  
  8. <!-- ============================================================ -->
  9. <!-- label markup -->
  10.  
  11. <doc:mode mode="label.markup" xmlns="">
  12. <refpurpose>Provides access to element labels</refpurpose>
  13. <refdescription>
  14. <para>Processing an element in the
  15. <literal role="mode">label.markup</literal> mode produces the
  16. element label.</para>
  17. <para>Trailing punctuation is not added to the label.
  18. </para>
  19. </refdescription>
  20. </doc:mode>
  21.  
  22. <xsl:template match="*" mode="intralabel.punctuation">
  23.   <xsl:text>.</xsl:text>
  24. </xsl:template>
  25.  
  26. <xsl:template match="*" mode="label.markup">
  27.   <xsl:message>
  28.     <xsl:text>Request for label of unexpected element: </xsl:text>
  29.     <xsl:value-of select="name(.)"/>
  30.   </xsl:message>
  31. </xsl:template>
  32.  
  33. <xsl:template match="set|book" mode="label.markup">
  34.   <xsl:if test="@label">
  35.     <xsl:value-of select="@label"/>
  36.   </xsl:if>
  37. </xsl:template>
  38.  
  39. <xsl:template match="part" mode="label.markup">
  40.   <xsl:choose>
  41.     <xsl:when test="@label">
  42.       <xsl:value-of select="@label"/>
  43.     </xsl:when>
  44.     <xsl:when test="$part.autolabel != 0">
  45.       <xsl:number from="book" count="part" format="I"/>
  46.     </xsl:when>
  47.   </xsl:choose>
  48. </xsl:template>
  49.  
  50. <xsl:template match="partintro" mode="label.markup">
  51.   <!-- no label -->
  52. </xsl:template>
  53.  
  54. <xsl:template match="preface" mode="label.markup">
  55.   <xsl:choose>
  56.     <xsl:when test="@label">
  57.       <xsl:value-of select="@label"/>
  58.     </xsl:when>
  59.     <xsl:when test="$preface.autolabel != 0">
  60.       <xsl:choose>
  61.         <xsl:when test="$label.from.part != 0 and ancestor::part">
  62.           <xsl:number from="part" count="preface" format="1" level="any"/>
  63.         </xsl:when>
  64.         <xsl:otherwise>
  65.           <xsl:number from="book" count="preface" format="1" level="any"/>
  66.         </xsl:otherwise>
  67.       </xsl:choose>
  68.     </xsl:when>
  69.   </xsl:choose>
  70. </xsl:template>
  71.  
  72. <xsl:template match="chapter" mode="label.markup">
  73.   <xsl:choose>
  74.     <xsl:when test="@label">
  75.       <xsl:value-of select="@label"/>
  76.     </xsl:when>
  77.     <xsl:when test="$chapter.autolabel != 0">
  78.       <xsl:choose>
  79.         <xsl:when test="$label.from.part != 0 and ancestor::part">
  80.           <xsl:number from="part" count="chapter" format="1" level="any"/>
  81.         </xsl:when>
  82.         <xsl:otherwise>
  83.           <xsl:number from="book" count="chapter" format="1" level="any"/>
  84.         </xsl:otherwise>
  85.       </xsl:choose>
  86.     </xsl:when>
  87.   </xsl:choose>
  88. </xsl:template>
  89.  
  90. <xsl:template match="appendix" mode="label.markup">
  91.   <xsl:choose>
  92.     <xsl:when test="@label">
  93.       <xsl:value-of select="@label"/>
  94.     </xsl:when>
  95.     <xsl:when test="$appendix.autolabel != 0">
  96.       <xsl:choose>
  97.         <xsl:when test="$label.from.part != 0 and ancestor::part">
  98.           <xsl:number from="part" count="appendix" format="A" level="any"/>
  99.         </xsl:when>
  100.         <xsl:otherwise>
  101.           <xsl:number from="book|article"
  102.                       count="appendix" format="A" level="any"/>
  103.         </xsl:otherwise>
  104.       </xsl:choose>
  105.     </xsl:when>
  106.   </xsl:choose>
  107. </xsl:template>
  108.  
  109. <xsl:template match="article" mode="label.markup">
  110.   <xsl:if test="@label">
  111.     <xsl:value-of select="@label"/>
  112.   </xsl:if>
  113. </xsl:template>
  114.  
  115. <xsl:template match="dedication|colophon" mode="label.markup">
  116.   <xsl:if test="@label">
  117.     <xsl:value-of select="@label"/>
  118.   </xsl:if>
  119. </xsl:template>
  120.  
  121. <xsl:template match="reference" mode="label.markup">
  122.   <xsl:choose>
  123.     <xsl:when test="@label">
  124.       <xsl:value-of select="@label"/>
  125.     </xsl:when>
  126.     <xsl:when test="$part.autolabel != 0">
  127.       <xsl:number from="book" count="reference" format="I" level="any"/>
  128.     </xsl:when>
  129.   </xsl:choose>
  130. </xsl:template>
  131.  
  132. <xsl:template match="refentry" mode="label.markup">
  133.   <xsl:if test="@label">
  134.     <xsl:value-of select="@label"/>
  135.   </xsl:if>
  136. </xsl:template>
  137.  
  138. <xsl:template match="section" mode="label.markup">
  139.   <!-- if this is a nested section, label the parent -->
  140.   <xsl:if test="local-name(..) = 'section'">
  141.     <xsl:variable name="parent.section.label">
  142.       <xsl:apply-templates select=".." mode="label.markup"/>
  143.     </xsl:variable>
  144.     <xsl:if test="$parent.section.label != ''">
  145.       <xsl:apply-templates select=".." mode="label.markup"/>
  146.       <xsl:apply-templates select=".." mode="intralabel.punctuation"/>
  147.     </xsl:if>
  148.   </xsl:if>
  149.  
  150.   <!-- if the parent is a component, maybe label that too -->
  151.   <xsl:variable name="parent.is.component">
  152.     <xsl:call-template name="is.component">
  153.       <xsl:with-param name="node" select=".."/>
  154.     </xsl:call-template>
  155.   </xsl:variable>
  156.  
  157.   <!-- does this section get labelled? -->
  158.   <xsl:variable name="label">
  159.     <xsl:call-template name="label.this.section">
  160.       <xsl:with-param name="section" select="."/>
  161.     </xsl:call-template>
  162.   </xsl:variable>
  163.  
  164.   <xsl:if test="$section.label.includes.component.label != 0
  165.                 and $parent.is.component != 0">
  166.     <xsl:variable name="parent.label">
  167.       <xsl:apply-templates select=".." mode="label.markup"/>
  168.     </xsl:variable>
  169.     <xsl:if test="$parent.label != ''">
  170.       <xsl:apply-templates select=".." mode="label.markup"/>
  171.       <xsl:apply-templates select=".." mode="intralabel.punctuation"/>
  172.     </xsl:if>
  173.   </xsl:if>
  174.  
  175. <!--
  176.   <xsl:message>
  177.     <xsl:value-of select="$label"/>, <xsl:number count="section"/>
  178.   </xsl:message>
  179. -->
  180.  
  181.   <xsl:choose>
  182.     <xsl:when test="@label">
  183.       <xsl:value-of select="@label"/>
  184.     </xsl:when>
  185.     <xsl:when test="$label != 0">
  186.       <xsl:number count="section"/>
  187.     </xsl:when>
  188.   </xsl:choose>
  189. </xsl:template>
  190.  
  191. <xsl:template match="sect1" mode="label.markup">
  192.   <!-- if the parent is a component, maybe label that too -->
  193.   <xsl:variable name="parent.is.component">
  194.     <xsl:call-template name="is.component">
  195.       <xsl:with-param name="node" select=".."/>
  196.     </xsl:call-template>
  197.   </xsl:variable>
  198.  
  199.   <xsl:if test="$section.label.includes.component.label != 0
  200.                 and $parent.is.component">
  201.     <xsl:variable name="parent.label">
  202.       <xsl:apply-templates select=".." mode="label.markup"/>
  203.     </xsl:variable>
  204.     <xsl:if test="$parent.label != ''">
  205.       <xsl:apply-templates select=".." mode="label.markup"/>
  206.       <xsl:apply-templates select=".." mode="intralabel.punctuation"/>
  207.     </xsl:if>
  208.   </xsl:if>
  209.  
  210.   <xsl:choose>
  211.     <xsl:when test="@label">
  212.       <xsl:value-of select="@label"/>
  213.     </xsl:when>
  214.     <xsl:when test="$section.autolabel != 0">
  215.       <xsl:number count="sect1"/>
  216.     </xsl:when>
  217.   </xsl:choose>
  218. </xsl:template>
  219.  
  220. <xsl:template match="sect2|sect3|sect4|sect5" mode="label.markup">
  221.   <!-- label the parent -->
  222.   <xsl:variable name="parent.label">
  223.     <xsl:apply-templates select=".." mode="label.markup"/>
  224.   </xsl:variable>
  225.   <xsl:if test="$parent.label != ''">
  226.     <xsl:apply-templates select=".." mode="label.markup"/>
  227.     <xsl:apply-templates select=".." mode="intralabel.punctuation"/>
  228.   </xsl:if>
  229.  
  230.   <xsl:choose>
  231.     <xsl:when test="@label">
  232.       <xsl:value-of select="@label"/>
  233.     </xsl:when>
  234.     <xsl:when test="$section.autolabel != 0">
  235.       <xsl:choose>
  236.         <xsl:when test="local-name(.) = 'sect2'">
  237.       <xsl:number count="sect2"/>
  238.     </xsl:when>
  239.     <xsl:when test="local-name(.) = 'sect3'">
  240.       <xsl:number count="sect3"/>
  241.     </xsl:when>
  242.     <xsl:when test="local-name(.) = 'sect4'">
  243.       <xsl:number count="sect4"/>
  244.     </xsl:when>
  245.     <xsl:when test="local-name(.) = 'sect5'">
  246.       <xsl:number count="sect5"/>
  247.     </xsl:when>
  248.     <xsl:otherwise>
  249.       <xsl:message>label.markup: this can't happen!</xsl:message>
  250.     </xsl:otherwise>
  251.       </xsl:choose>
  252.     </xsl:when>
  253.   </xsl:choose>
  254. </xsl:template>
  255.  
  256. <xsl:template match="refsect1" mode="label.markup">
  257.   <xsl:choose>
  258.     <xsl:when test="@label">
  259.       <xsl:value-of select="@label"/>
  260.     </xsl:when>
  261.     <xsl:when test="$section.autolabel != 0">
  262.       <xsl:number count="refsect1"/>
  263.     </xsl:when>
  264.   </xsl:choose>
  265. </xsl:template>
  266.  
  267. <xsl:template match="refsect2|refsect3" mode="label.markup">
  268.   <!-- label the parent -->
  269.   <xsl:variable name="parent.label">
  270.     <xsl:apply-templates select=".." mode="label.markup"/>
  271.   </xsl:variable>
  272.   <xsl:if test="$parent.label != ''">
  273.     <xsl:apply-templates select=".." mode="label.markup"/>
  274.     <xsl:apply-templates select=".." mode="intralabel.punctuation"/>
  275.   </xsl:if>
  276.  
  277.   <xsl:choose>
  278.     <xsl:when test="@label">
  279.       <xsl:value-of select="@label"/>
  280.     </xsl:when>
  281.     <xsl:when test="$section.autolabel != 0">
  282.       <xsl:choose>
  283.         <xsl:when test="local-name(.) = 'refsect2'">
  284.       <xsl:number count="refsect2"/>
  285.     </xsl:when>
  286.         <xsl:otherwise>
  287.       <xsl:number count="refsect3"/>
  288.     </xsl:otherwise>
  289.       </xsl:choose>
  290.     </xsl:when>
  291.   </xsl:choose>
  292. </xsl:template>
  293.  
  294. <xsl:template match="simplesect" mode="label.markup">
  295.   <!-- if this is a nested section, label the parent -->
  296.   <xsl:if test="local-name(..) = 'section'
  297.                 or local-name(..) = 'sect1'
  298.                 or local-name(..) = 'sect2'
  299.                 or local-name(..) = 'sect3'
  300.                 or local-name(..) = 'sect4'
  301.                 or local-name(..) = 'sect5'">
  302.     <xsl:variable name="parent.section.label">
  303.       <xsl:apply-templates select=".." mode="label.markup"/>
  304.     </xsl:variable>
  305.     <xsl:if test="$parent.section.label != ''">
  306.       <xsl:apply-templates select=".." mode="label.markup"/>
  307.       <xsl:apply-templates select=".." mode="intralabel.punctuation"/>
  308.     </xsl:if>
  309.   </xsl:if>
  310.  
  311.   <!-- if the parent is a component, maybe label that too -->
  312.   <xsl:variable name="parent.is.component">
  313.     <xsl:call-template name="is.component">
  314.       <xsl:with-param name="node" select=".."/>
  315.     </xsl:call-template>
  316.   </xsl:variable>
  317.  
  318.   <!-- does this section get labelled? -->
  319.   <xsl:variable name="label">
  320.     <xsl:call-template name="label.this.section">
  321.       <xsl:with-param name="section" select="."/>
  322.     </xsl:call-template>
  323.   </xsl:variable>
  324.  
  325.   <xsl:if test="$section.label.includes.component.label != 0
  326.                 and $parent.is.component != 0">
  327.     <xsl:variable name="parent.label">
  328.       <xsl:apply-templates select=".." mode="label.markup"/>
  329.     </xsl:variable>
  330.     <xsl:if test="$parent.label != ''">
  331.       <xsl:apply-templates select=".." mode="label.markup"/>
  332.       <xsl:apply-templates select=".." mode="intralabel.punctuation"/>
  333.     </xsl:if>
  334.   </xsl:if>
  335.  
  336.   <xsl:choose>
  337.     <xsl:when test="@label">
  338.       <xsl:value-of select="@label"/>
  339.     </xsl:when>
  340.     <xsl:when test="$label != 0">
  341.       <xsl:number count="simplesect"/>
  342.     </xsl:when>
  343.   </xsl:choose>
  344. </xsl:template>
  345.  
  346. <xsl:template match="qandadiv" mode="label.markup">
  347.   <xsl:variable name="lparent" select="(ancestor::set
  348.                                        |ancestor::book
  349.                                        |ancestor::chapter
  350.                                        |ancestor::appendix
  351.                                        |ancestor::preface
  352.                                        |ancestor::section
  353.                                        |ancestor::simplesect
  354.                                        |ancestor::sect1
  355.                                        |ancestor::sect2
  356.                                        |ancestor::sect3
  357.                                        |ancestor::sect4
  358.                                        |ancestor::sect5
  359.                                        |ancestor::refsect1
  360.                                        |ancestor::refsect2
  361.                                        |ancestor::refsect3)[last()]"/>
  362.  
  363.   <xsl:variable name="lparent.prefix">
  364.     <xsl:apply-templates select="$lparent" mode="label.markup"/>
  365.   </xsl:variable>
  366.  
  367.   <xsl:variable name="prefix">
  368.     <xsl:if test="$qanda.inherit.numeration != 0">
  369.       <xsl:if test="$lparent.prefix != ''">
  370.         <xsl:apply-templates select="$lparent" mode="label.markup"/>
  371.         <xsl:apply-templates select="$lparent" mode="intralabel.punctuation"/>
  372.       </xsl:if>
  373.     </xsl:if>
  374.   </xsl:variable>
  375.  
  376.   <xsl:choose>
  377.     <xsl:when test="@label">
  378.       <xsl:value-of select="$prefix"/>
  379.       <xsl:value-of select="@label"/>
  380.     </xsl:when>
  381.     <xsl:when test="$qandadiv.autolabel != 0">
  382.       <xsl:value-of select="$prefix"/>
  383.       <xsl:number level="multiple" count="qandadiv" format="1"/>
  384.     </xsl:when>
  385.   </xsl:choose>
  386. </xsl:template>
  387.  
  388. <xsl:template match="question|answer" mode="label.markup">
  389.   <xsl:variable name="lparent" select="(ancestor::set
  390.                                        |ancestor::book
  391.                                        |ancestor::chapter
  392.                                        |ancestor::appendix
  393.                                        |ancestor::preface
  394.                                        |ancestor::section
  395.                                        |ancestor::simplesect
  396.                                        |ancestor::sect1
  397.                                        |ancestor::sect2
  398.                                        |ancestor::sect3
  399.                                        |ancestor::sect4
  400.                                        |ancestor::sect5
  401.                                        |ancestor::refsect1
  402.                                        |ancestor::refsect2
  403.                                        |ancestor::refsect3)[last()]"/>
  404.  
  405.   <xsl:variable name="lparent.prefix">
  406.     <xsl:apply-templates select="$lparent" mode="label.markup"/>
  407.   </xsl:variable>
  408.  
  409.   <xsl:variable name="prefix">
  410.     <xsl:if test="$qanda.inherit.numeration != 0">
  411.       <xsl:if test="$lparent.prefix != ''">
  412.         <xsl:apply-templates select="$lparent" mode="label.markup"/>
  413.         <xsl:apply-templates select="$lparent" mode="intralabel.punctuation"/>
  414.       </xsl:if>
  415.       <xsl:if test="ancestor::qandadiv">
  416.         <xsl:apply-templates select="ancestor::qandadiv[1]" mode="label.markup"/>
  417.         <xsl:apply-templates select="ancestor::qandadiv[1]"
  418.                              mode="intralabel.punctuation"/>
  419.       </xsl:if>
  420.     </xsl:if>
  421.   </xsl:variable>
  422.  
  423.   <xsl:variable name="inhlabel"
  424.                 select="ancestor-or-self::qandaset/@defaultlabel[1]"/>
  425.  
  426.   <xsl:variable name="deflabel">
  427.     <xsl:choose>
  428.       <xsl:when test="$inhlabel != ''">
  429.         <xsl:value-of select="$inhlabel"/>
  430.       </xsl:when>
  431.       <xsl:otherwise>
  432.         <xsl:value-of select="$qanda.defaultlabel"/>
  433.       </xsl:otherwise>
  434.     </xsl:choose>
  435.   </xsl:variable>
  436.  
  437.   <xsl:variable name="label" select="label"/>
  438.  
  439.   <xsl:choose>
  440.     <xsl:when test="count($label)>0">
  441.       <xsl:apply-templates select="$label"/>
  442.     </xsl:when>
  443.  
  444.     <xsl:when test="$deflabel = 'qanda' and local-name(.) = 'question'">
  445.       <xsl:call-template name="gentext">
  446.         <xsl:with-param name="key" select="'Question'"/>
  447.       </xsl:call-template>
  448.     </xsl:when>
  449.  
  450.     <xsl:when test="$deflabel = 'qanda' and local-name(.) = 'answer'">
  451.       <xsl:call-template name="gentext">
  452.         <xsl:with-param name="key" select="'Answer'"/>
  453.       </xsl:call-template>
  454.     </xsl:when>
  455.  
  456.     <xsl:when test="$deflabel = 'number' and local-name(.) = 'question'">
  457.       <xsl:value-of select="$prefix"/>
  458.       <xsl:number level="multiple" count="qandaentry" format="1"/>
  459.       <xsl:text>. </xsl:text>
  460.     </xsl:when>
  461.   </xsl:choose>
  462. </xsl:template>
  463.  
  464. <xsl:template match="bibliography|glossary|index" mode="label.markup">
  465.   <xsl:if test="@label">
  466.     <xsl:value-of select="@label"/>
  467.   </xsl:if>
  468. </xsl:template>
  469.  
  470. <xsl:template match="figure|table|example|equation|procedure"
  471.               mode="label.markup">
  472.   <xsl:variable name="pchap"
  473.                 select="ancestor::chapter
  474.                         |ancestor::appendix
  475.                         |ancestor::article[ancestor::book]"/>
  476.  
  477.   <xsl:variable name="prefix">
  478.     <xsl:if test="count($pchap) > 0">
  479.       <xsl:apply-templates select="$pchap" mode="label.markup"/>
  480.     </xsl:if>
  481.   </xsl:variable>
  482.  
  483.   <xsl:choose>
  484.     <xsl:when test="@label">
  485.       <xsl:value-of select="@label"/>
  486.     </xsl:when>
  487.     <xsl:otherwise>
  488.       <xsl:choose>
  489.         <xsl:when test="count($pchap)>0">
  490.           <xsl:if test="$prefix != ''">
  491.             <xsl:apply-templates select="$pchap" mode="label.markup"/>
  492.             <xsl:apply-templates select="$pchap" mode="intralabel.punctuation"/>
  493.           </xsl:if>
  494.           <xsl:number format="1" from="chapter|appendix" level="any"/>
  495.         </xsl:when>
  496.         <xsl:otherwise>
  497.           <xsl:number format="1" from="book|article" level="any"/>
  498.         </xsl:otherwise>
  499.       </xsl:choose>
  500.     </xsl:otherwise>
  501.   </xsl:choose>
  502. </xsl:template>
  503.  
  504. <xsl:template match="orderedlist/listitem" mode="label.markup">
  505.   <xsl:variable name="numeration">
  506.     <xsl:call-template name="list.numeration">
  507.       <xsl:with-param name="node" select="parent::orderedlist"/>
  508.     </xsl:call-template>
  509.   </xsl:variable>
  510.  
  511.   <xsl:variable name="type">
  512.     <xsl:choose>
  513.       <xsl:when test="$numeration='arabic'">1</xsl:when>
  514.       <xsl:when test="$numeration='loweralpha'">a</xsl:when>
  515.       <xsl:when test="$numeration='lowerroman'">i</xsl:when>
  516.       <xsl:when test="$numeration='upperalpha'">A</xsl:when>
  517.       <xsl:when test="$numeration='upperroman'">I</xsl:when>
  518.       <!-- What!? This should never happen -->
  519.       <xsl:otherwise>
  520.         <xsl:message>
  521.           <xsl:text>Unexpected numeration: </xsl:text>
  522.           <xsl:value-of select="$numeration"/>
  523.         </xsl:message>
  524.         <xsl:value-of select="1."/>
  525.       </xsl:otherwise>
  526.     </xsl:choose>
  527.   </xsl:variable>
  528.  
  529.   <xsl:number count="listitem" format="{$type}"/>
  530. </xsl:template>
  531.  
  532. <xsl:template match="abstract" mode="label.markup">
  533.   <!-- nop -->
  534. </xsl:template>
  535.  
  536. <!-- ============================================================ -->
  537.  
  538. <xsl:template name="label.this.section">
  539.   <xsl:param name="section" select="."/>
  540.   <xsl:value-of select="$section.autolabel"/>
  541. </xsl:template>
  542.  
  543. <doc:template name="label.this.section" xmlns="">
  544. <refpurpose>Returns true if $section should be labelled</refpurpose>
  545. <refdescription>
  546. <para>Returns true if the specified section should be labelled.
  547. By default, this template simply returns $section.autolabel, but
  548. custom stylesheets may override it to get more selective behavior.</para>
  549. </refdescription>
  550. </doc:template>
  551.  
  552. <!-- ============================================================ -->
  553.  
  554. </xsl:stylesheet>
  555. This resource fork intentionally left blank   ˇˇ